**MAVEN ANALYTICS GUIDED PROJECT – 2**

**MoMA Art Explorer**

Build an interactive tool to explore the artwork at the Museum of Modern Art (MoMA)

*Excel | Advanced | Miscellaneous*

***PROJECT BRIEF***

**The Situation:-** You work as a Research Intern at the Museum of Modern Art (MoMA) in New York City, one of the most popular and visited art museums.

**The Assignment:-** The Museum’s Curator has given you access the database of artwork on display, and needs your help in exploring each artist’s progression interactively. Your task is to create a tool that allows the curator to select a nationality, artist, and minimum year of creation and display their earliest artwork.

**The Objectives:-** You must complete the following objectives in this project:-

1. Clean & prepare the data
2. Extract artist information
3. Display their work

***THE DATASET***

Dataset Name:- The Museum of Modern Art (MoMA) Collection

File Type:- CSV

Data Structure:- Multiple Tables

No. of Records:- 157630

No. of Fields:- 30

Dataset Description:- This research dataset contains 157,630 records, representing all of the works that have been accessioned into MoMA’s collection and cataloged in their database. It includes basic metadata for each work, including title, artist, date made, medium, dimensions, and date acquired by the Museum. Some of these records have incomplete information and are noted as “not Curator Approved.”

Recommended Analysis:-

* How modern are the artworks at the Museum?
* Which artists are featured the most?
* Are there any trends in the dates of acquisition?
* What types of artwork are most common?

Dataset Link:-

***OBJECTIVE – 1 (CLEAN & PREPARE THE DATA)***

Your first objective is to clean the artwork data by looking up the artist(s) for each piece and extracting it's date of creation.

**Task:-**

1. Open the MoMA\_OnView.xslx file and review the data in each tab

Hint:- Make sure it's "MoMA\_OnView.xlsx" and not the individual CSV files

1. Look up the Artist for each artwork by using the ConstituentID field

Hint:- Modify the lookup\_value in the XLOOKUP function by splitting the ConstituentID by each comma, then join the results so that you have all the artists for each artwork in a single cell

=XLOOKUP(C2,Artists!A:.A,Artists!B:.B)

=XLOOKUP(TEXTSPLIT(C7,","),Artists!A:.A,Artists!B:.B)

=XLOOKUP(TEXTSPLIT(C7,",")\*1,Artists!A:.A,Artists!B:.B)

=TEXTJOIN(", ",TRUE,XLOOKUP(TEXTSPLIT(C7,",")\*1,Artists!A:.A,Artists!B:.B))

1. Create a CleanDate column that extract the first 4 numeric characters from each Date

Hint:- Use REGEXEXTRACT()

=REGEXEXTRACT(E2,"\d{4}")

=REGEXEXTRACT(E2,"\d{4}")\*1

1. Clean the OnView column by removing the “MoMA” prefix and quotation marks

Hint:- Use the Find & Replace tool

***OBJECTIVE – 2 (EXTRACT ARTIST INFORMATION)***

Your second objective is to create dependent dropdown lists for nationality and artist, and display their number of artworks and their earliest & latest work on display.

**Task:-**

1. In a new sheet, create a dropdown list with artists’ Nationality in alphabetical order

Hint:- Use SORT and UNIQUE to create the source data for the data validation list

=UNIQUE(Artists!D2:D662)

=SORT(UNIQUE(Artists!D2:D662))

=DROP(SORT(UNIQUE(Artists!D2:D662)), -1)

1. Create a second, dependent dropdown list with the Artists for the selected nationality

Hint:- Use FILTER and the selected Nationality to create the source data for the data validation list

=FILTER(Artists!B:B,Artists!D:D='Art Explorer'!C3)

=SORT(FILTER(Artists!B:B,Artists!D:D='Art Explorer'!C3))

1. Calculate the number of Artworks on display for the selected artist

Hint:- Use wilcard characters in the COUNTIFS function

=COUNTIFS(Artworks!D:D,'Art Explorer'!C4)

=COUNTIFS(Artworks!D:D,"\*"&C4&"\*")

1. Return the CleanDate for the earliest and latest artwork on display for the selected artist

Hint:- Use MINIFS and MAXIFS with the same wildcard characters

=MINIFS(Artworks!F:F,Artworks!D:D,"\*"&C4&"\*")

=MAXIFS(Artworks!F:F,Artworks!D:D,"\*"&C4&"\*")

***OBJECTIVE – 3 (DISPLAY THEIR WORK)***

Your final objective is to return additional information on the selected artist's earliest work after a certain date, along with the image of the artwork itself

**Task:-**

1. Return the Title, CleanDate, Medium, Dimensions, Classification, Department, DateAcquired, ImageURL, and OnView for each of the selected artist’s artworks

Hint:- Use ISNUMBER & SEARCH for the FILTER criteria

=FILTER(Artworks!B:B,ISNUMBER(SEARCH(C4,Artworks!D:D)))

=FILTER(HSTACK(Artworks!B:B,Artworks!F:K,Artworks!M:N),ISNUMBER(SEARCH(C4,Artworks!D:D)))

1. Create a new data validation rule where the user can type in the Min Year to filter the selected artist’s work by

Hint:- Add data validation so the user cannot enter a year outside of their range of work

1. Incorporate the Min Year into the filter criteria for the artwork returned

Hint:- Use the \* operator as the AND condition

=FILTER(HSTACK(Artworks!B:B,Artworks!F:K,Artworks!M:N),ISNUMBER(SEARCH(C4,Artworks!D:D))\*(Artworks!F:F>=C9))

1. Filter and transpose the list so that you only show the details for their earliest artwork

Hint:- Use SORT, TAKE, and TRANSPOSE

=SORT(FILTER(HSTACK(Artworks!B:B,Artworks!F:K,Artworks!M:N),ISNUMBER(SEARCH(C4,Artworks!D:D))\*(Artworks!F:F>=C9)),2)

=TAKE(SORT(FILTER(HSTACK(Artworks!B:B,Artworks!F:K,Artworks!M:N),ISNUMBER(SEARCH(C4,Artworks!D:D))\*(Artworks!F:F>=C9)),2),1)

=TRANSPOSE(TAKE(SORT(FILTER(HSTACK(Artworks!B:B,Artworks!F:K,Artworks!M:N),ISNUMBER(SEARCH(C4,Artworks!D:D))\*(Artworks!F:F>=C9)),2),1))

1. Use the ImageURL to display the artwork inside of a cell

Hint:- Use the IMAGE function

***FINAL PROJECT QUESTION***

Answer the following question to validate your completed project.

Q) What is the title of Mexican artist Diego Rivera's earliest work on display?

A) Cubist Landscape